;-------------------------------------------------------------
;   mIRCstats Automation Control (mAC) v1.21
;   (c)1999 azteq, aka Del
;   email: xxx@xxx.xxx
;   loc'n: ChatNet
;-------------------------------------------------------------

dialog ms.config {
  title "mIRCstats Automation Control Panel"
  size -1 -1 640 370

  box "Update Freq", 100, 5 5 130 78,

  radio "Every", 102, 10 23 50 15,
  edit "", 103, 60 20 30 21,
  text "hours", 104, 92 23 40 15,

  radio "Every", 105, 10 49 50 15,
  edit "", 106, 60 46 30 21,
  text "days", 107, 92 49 40 15,

  box "mIRCstats program location", 200, 140 5 495 63,

  edit "", 201, 145 19 240 23, autohs
  button "Browse", 202, 390 20 50 21,
  check "Automatic Operation", 203, 146 46 120 15,
  check "Reuse Chan Settings", 204, 291 46 120 15,

  box " Configuration Options   ", 300, 5 75 631 211,

  text "Channel:", 301, 11 88 50 15,
  edit "", 302, 10 100 100 23, autohs
  list 303, 10 121 100 88, vsbar

  button "Save", 304, 113 100 45 23,
  button "Delete", 305, 113 126 45 21,
  button "Update", 306, 113 160 45 21,
  button "Upload", 307, 113 184 45 21,

  text "ftp hostname:", 308, 165 88 120 15,
  check "Enable FTP", 326, 327 87 80 15, left
  edit "", 309, 164 101 244 23, autohs

  text "ftp login:", 310, 165 127 100 15,
  edit "", 311, 164 140 122 23, autohs

  text "password:", 312, 292 127 100 15,
  edit "", 313, 291 140 117 23, autohs pass

  text "Remote location:", 314, 165 166 100 15,
  edit "", 315, 164 179 122 23, autohs

  text "Config file:", 316, 292 166 100 15,
  edit "", 317, 291 179 117 23, autohs

  text "Log file:", 318, 11 205 100 15,
  edit "", 319, 10 218 145 23, autohs
  button "Browse", 320, 160 219 45 21,

  text ".html file:", 321, 213 205 100 15,
  edit "", 322, 212 218 145 23, autohs
  button "Browse", 323, 362 219 45 21,

  check "Set topic on update:", 324, 11 244 160 15,
  check "Say in Channel:", 337, 170 244 140 15,
  edit "", 325, 10 258 398 23, autohs, disable

  text "bot ftp:", 327, 415 88 120 15,
  check "Enable log DL", 329, 538 87 91 15, left
  edit "", 328, 414 101 216 23, autohs

  text "bot ftp login:", 330, 415 127 100 15,
  edit "", 331, 414 140 108 23, autohs

  text "bot ftp password:", 332, 528 127 100 15,
  edit "", 333, 527 140 103 23, autohs pass

  text "bot log path+file:", 334, 415 166 180 15,
  edit "", 335, 414 179 216 23, autohs
  check "Incremental Log", 336, 534 165 95 15, left

  box "", 400, 5 289 630 45,

  button "Update + Upload All", 401, 12 303 110 23,
  button "Save Options", 402, 127 303 90 23,
  button "Ok", 1, 348 303 90 23, default, ok
  button "Cancel", 403, 443 303 90 23, cancel
  button "Help Me!", 404, 538 303 90 23,

  box "", 50, 5 335 630 27,
  text "Welcome to mIRCstats Automation Control Panel", 51, 12 345 433 15,
}

on 1:DIALOG:ms.config:init:0 {
  did -o ms.config 103 1 $readini mircstats.ini Global FreqHour
  did -o ms.config 106 1 $readini mircstats.ini Global FreqDay 
  if ($readini mircstats.ini Global FreqType == h) {
    did -u ms.config 106
    did -b ms.config 106
    did -c ms.config 102
  }
  else {
    did -u ms.config 103
    did -b ms.config 103
    did -c ms.config 105 
  }
  did -o ms.config 201 1 $readini mircstats.ini Global Program
  if ($readini mircstats.ini Global State == a) { did -c ms.config 203 }
  if ($readini mircstats.ini Global Reuse == 1) { did -c ms.config 204 }
  set %ms.chans $readini mircstats.ini Global Chans
  if (%ms.chans != $null) {
    set %ms.chancount $numtok(%ms.chans, 44)
    :ms.cPchanloop
    did -a ms.config 303 $gettok(%ms.chans, %ms.chancount, 44)
    dec %ms.chancount
    if (%ms.chancount > 0) { goto ms.cPchanloop }
    unset %ms.chan*
    did -f ms.config 1
  }
  did -c ms.config 326
  /ms.botstate d
}

on 1:DIALOG:ms.config:sclick:*: {
  if ($did == 102) {
    if ($did(102).state == 1) {
      did -e ms.config 103
      did -u ms.config 106
      did -b ms.config 106
    }
  }
  if ($did == 105) {
    if ($did(105).state == 1) {
      did -e ms.config 106
      did -u ms.config 103
      did -b ms.config 103
    }
  }
  if ($did == 202) { .timer -m 1 1 /ms.browse 201 Select Location of mIRCstats program file: }
  if ($did == 303) {
    if ($did(302).text != $null) { /ms.saveChan $did(302).text }
    /ms.loadChan $did(303, $did(303, 1).sel).text
  }
  if ($did == 304) { /ms.saveChan $did(302).text }
  if ($did == 305) { /ms.delChan $did(302).text $did(303, 1).sel }
  if ($did == 306) {
    unset %ms.dAfullupdate
    if ($did(329).state == 1) { /ms.botdownload $did(302).text }
    else { /ms.update $did(302).text }
  }
  if ($did == 307) {
    unset %ms.dAfullupdate
    if ($readini mircstats.ini $did(302).text ftpState == e) { /ms.upload $did(302).text }
  }
  if ($did == 320) { .timer -m 1 1 /ms.browse 319 Select Location of Log file for this channel: }
  if ($did == 323) { .timer -m 1 1 /ms.browse 322 Select Location of .html file for this channel: }
  if ($did == 324) {
    if (($did(324).state == 1) && ($did(337).state == 0)) { did -e ms.config 325 }
    if (($did(324).state == 0) && ($did(337).state == 0)) { did -b ms.config 325 }
  }
  if ($did == 337) {
    if (($did(337).state == 1) && ($did(324).state == 0)) { did -e ms.config 325 }
    if (($did(337).state == 0) && ($did(324).state == 0)) { did -b ms.config 325 }
  }
  if ($did == 326) {
    if ($did(326).state == 1) { /ms.ftpstate e }
    else { /ms.ftpstate d }
  }
  if ($did == 329) {
    if ($did(329).state == 1) { /ms.botstate e }
    else { /ms.botstate d }
  }
  if ($did == 401) { set %ms.FUnotbytimer 1 | /ms.doall }
  if ($did == 402) { /ms.saveOpts }
  if ($did == 404) { run http://mAC.scriptmania.com/helplink.html }
  if ($did == 1) {
    /ms.saveOpts
    /ms.saveChan $did(302).text
    if ($did(203).state == 1) { /ms.enable }
    else { /ms.disable }
  }
}

on 1:DIALOG:ms.config:edit:*: {
  if ($did == 302) {
    if (($chr(44) !isin $did(302).text) && ($left($did(302).text, 1) == $chr(35)) && ($len($did(302).text) > 1)) {
      set %ms.ceChanList $readini mircstats.ini Global Chans
      if ($istok(%ms.ceChanList, $did(302).text, 44) == $false) { /ms.newChan $did(302).text }
      unset %ms.ceChanList
    }
    if ($did == 335) {
      set %ms.botLogName $did(335).text
      set %ms.botLogName $gettok(%ms.botLogName, $numtok(%ms.botLogName, 47), 47)
      did -o ms.config 319 1 $mircdir $+ %ms.botLogName
      unset %ms.botLogName
    }
  }
}

on 1:CONNECT: {
  if ($readini mircstats.ini Global State == a) { ms.enable }
}

on 1:TEXT:*:#: {
  if (($1 == !nextupdate) && ($ms.isInChans($chan) == $true)) {
    set %ms.nUtemp $readini mircstats.ini Global LTS
    set %ms.nUtemp $gettok(%ms.nUtemp, 2, 32)
    if ($timer(.ms.enable) != $null) { set %ms.nUtemp $calc((%ms.nUtemp + $timer(.ms.enable).delay) - $ctime) }
    elseif ($timer(.ms.autoupdate) != $null) { set %ms.nUtemp $calc((%ms.nUtemp + $timer(.ms.autoupdate).delay) - $ctime) }
    notice $nick 2[12m10A12C2] 6-> 14Next $chan Stats Update in $duration(%ms.nUtemp)
    unset %ms.nUtemp
  }
}

on 1:LOAD: { load -rs mstats1.mrc }

menu status,menubar {
  -
  mIRCstats
  .Control Panel:/mircstats
  .Automatic ( $+ $ms.trueState $+ )
  ..$ms.state:/ms.changestate
  .Update + Upload All:/ms.doallpopup
  -
}